ESP32 Over-the-Air (OTA) Updates using Kaa Platform

// This is a basic Kaa OTA implementation for a generic ESP32 microcontroller
#include <WiFi.h>
#include <PubSubClient.h>
#include <ArduinoJson.h>
#include <esp_err.h>
#include <esp_http_client.h>
#include <esp_https_ota.h>
#include <esp_crt_bundle.h>

// --- IMPORTANT - WiFi credentials and MQTT server configuration
const char* ssid = "<your-wifi-name>";            // WiFi name (case-sensitive)
const char* password = "<your-wifi-password>";    // WiFi password

const String TOKEN = "<your-endpoint-token>";     // Endpoint token - provided during device provisioning
const String APP_VERSION = "<your-app-version>";  // Application version
const String CURRENT_VERSION = "1.0.0";           // Version of the current firmware

const char* mqttServer = "mqtt.cloud.kaaiot.com";   // MQTT server address
const char* client_id = "19665f9f";                 // MQTT client ID

// Initialize the MQTT client and WiFi client
WiFiClient espClient;              
PubSubClient client(espClient);   

// Initial setup function before main `void loop()`
void setup() {
  // Open serial connection
  Serial.begin(9600);

  // Set up MQTT server and callback for handling OTA messages
  client.setServer(mqttServer, 1883);
  client.setCallback(handleOtaUpdate);

  // Establish initial server connection
  initServerConnection();

  // Allocate memory for MQTT payloads
  if (client.setBufferSize(1024)) {
    Serial.println("Successfully reallocated internal buffer size");
  } else {
    Serial.println("Failed to reallocated internal buffer size");
  }

  delay(1000);

  // Report current firmware version and request a new firmware update
  reportCurrentFirmwareVersion();
  requestNewFirmware();
}

// Main loop function
void loop() {
  // Maintain server connection and handle periodic MQTT work
  initServerConnection();
  delay(1000);
}

// Report the current firmware version to the server
void reportCurrentFirmwareVersion() {
  String reportTopic = "kp1/" + APP_VERSION + "/cmx_ota/" + TOKEN + "/applied/json";
  String reportPayload = "{\"configId\":\"" + CURRENT_VERSION + "\"}";
  Serial.println("Reporting current firmware version on topic: " + reportTopic + " and payload: " + reportPayload);
  client.publish(reportTopic.c_str(), reportPayload.c_str());
}

// Request a new firmware update from the server
void requestNewFirmware() {
  int requestID = random(0, 99);  // Generate a random request ID to avoid conflicts
  String firmwareRequestTopic = "kp1/" + APP_VERSION + "/cmx_ota/" + TOKEN + "/config/json/" + requestID;
  Serial.println("Requesting firmware using topic: " + firmwareRequestTopic);
  client.publish(firmwareRequestTopic.c_str(), "{\"observe\":true}"); // Use observe to indicate acceptance of server push
}

// Establish WiFi and MQTT server connections
void initServerConnection() {
  setupWifi();
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
}

// Handle OTA update messages from the MQTT server
void handleOtaUpdate(char* topic, byte* payload, unsigned int length) {
  Serial.printf("\nHandling firmware update message on topic: %s and payload: ", topic);

  // Parse incoming JSON payload
  DynamicJsonDocument doc(1024);
  deserializeJson(doc, payload, length);
  JsonVariant json_var = doc.as<JsonVariant>();
  Serial.println(json_var.as<String>());

  // Check if the payload contains valid OTA information
  if (json_var.isNull()) {
    Serial.println("No new firmware version is available");
    return;
  }

  // Confirm that the payload is valid
  unsigned int statusCode = json_var["statusCode"].as<unsigned int>();
  if (statusCode != 200) {
    String reasonPhrase = json_var["reasonPhrase"].as<String>();
    Serial.printf("Firmware message's status code is not 200, but: %d\n", statusCode);
    Serial.println("Response: " + reasonPhrase);
    return;
  }

  // Extract the firmware download link, which may be located in one of two different places depending on the OTA update configuration.
  String systemFileLink = json_var["config"]["system"]["files"][0].as<String>();
  String downloadLink = json_var["config"]["link"].as<String>();
  String newVersionNumber = json_var["configId"].as<String>();
  // Determine which firmware link to use
  String firmwareLink = systemFileLink && !systemFileLink.equals(String("null")) 
    ? systemFileLink 
    : downloadLink && !downloadLink.equals(String("null"))
    ? downloadLink 
    : "";

  Serial.println("firmwareLink: " + firmwareLink);
  
  // Attempt the firmware update
  Serial.println("Updating...");
  esp_err_t ret = performFirmwareUpgrade(firmwareLink);

  // Handle the result of the OTA update
  if (ret == ESP_OK) {
    Serial.println("Firmware was updated successfuly from '" + CURRENT_VERSION + "' to '" + newVersionNumber + "'. Restarting...");
    esp_restart();
  } else {
    Serial.println("Firmware update failed. Skipping...");
  }
}

// Perform OTA firmware upgrade
esp_err_t performFirmwareUpgrade(String firmwareLink) {
  esp_http_client_config_t config = {
    .url = firmwareLink.c_str(),
    .crt_bundle_attach = esp_crt_bundle_attach, // Default certificate bundle
  };
  esp_https_ota_config_t ota_config = {
    .http_config = &config,
  };

  esp_err_t ret = esp_https_ota(&ota_config);
  return ret;
}

// Setup WiFi connection
void setupWifi() {
  if (WiFi.status() != WL_CONNECTED) {
    delay(200);
    Serial.println();
    Serial.printf("Connecting to [%s]\n", ssid);
    WiFi.begin(ssid, password);
    connectWiFi();
  }
}

// Wait until connected to WiFi
void connectWiFi() {
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.println("Connecting to WiFi...");
  }
  Serial.println();
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

// Attempt to reconnect to the MQTT server if disconnected
void reconnect() {
  while (!client.connected()) {
    Serial.println("Attempting MQTT connection...");
    
    if (client.connect(client_id)) {
      Serial.println("Connected to WiFi");
      subscribeToFirmwareUpdates();
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

// Subscribe to firmware-related topics for OTA updates
void subscribeToFirmwareUpdates() {
  String serverPushOnConnect = "kp1/" + APP_VERSION + "/cmx_ota/" + TOKEN + "/config/json/#";
  client.subscribe(serverPushOnConnect.c_str());
  Serial.println("Subscribed to server firmware push on topic: " + serverPushOnConnect);

  String serverFirmwareResponse = "kp1/" + APP_VERSION + "/cmx_ota/" + TOKEN + "/config/json/status/#";
  client.subscribe(serverFirmwareResponse.c_str());
  Serial.println("Subscribed to server firmware response on topic: " + serverFirmwareResponse);

  String serverFirmwareErrorResponse = "kp1/" + APP_VERSION + "/cmx_ota/" + TOKEN + "/config/json/status/error";
  client.subscribe(serverFirmwareErrorResponse.c_str());
  Serial.println("Subscribed to server firmware response on topic: " + serverFirmwareErrorResponse);
}